(*~\Глагол\Отделы\Иное~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                        ОТДЕЛ Набор;
(*============================================================================*)
(* НАЗНАЧЕНИЕ: список Наборов (ДвуКонцевая Очередь из односвязных звеньев)    *) 
(*============================================================================*)
ВИД
  Вид-     =НАБОР КОН;   (* опорный вид (абстрактный предок) других НАБОРов *)
  Доступ-  =ДОСТУП К Вид;

  Звено-   =ДОСТУП К ВидЗвено;
  ВидЗвено-=НАБОР
    данные-:Доступ;
    след-  :Звено 
  КОН;

  Список-=НАБОР         (* ДвуКонцевая Очередь из односвязных звеньев *)
    звеньев-:ЦЕЛ;
    первоеЗвено:Звено;
    последнееЗвено:Звено
  КОН;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОчиститьСписок-(список+:Список);
УКАЗ
  список.звеньев:=0;
  список.первоеЗвено:=ПУСТО;
  список.последнееЗвено:=ПУСТО
КОН ОчиститьСписок;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ВКонецСписка-(список+:Список; данные:Доступ);
(* Цель:  создать и присоединить новое звено вместе с данными в конец списка *)
ПЕР
  звено:Звено;
УКАЗ
  СОЗДАТЬ(звено);
  звено.данные:=данные;
  ЕСЛИ список.первоеЗвено = ПУСТО ТО
    список.первоеЗвено:=звено;
    список.последнееЗвено:=звено
  ИНАЧЕ
    список.последнееЗвено.след:=звено;
    список.последнееЗвено:=звено
  КОН;
  УВЕЛИЧИТЬ(список.звеньев)
КОН ВКонецСписка;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ПервоеЗвено-(список-:Список):Звено;
(* Цель:  выдать первое звено списка *)
УКАЗ
  ВОЗВРАТ список.первоеЗвено
КОН ПервоеЗвено;

КОН Набор.