Азбука программирования на Глаголе

Аз да буки, да и конец науки

Азъ Буки Веде Глаголь Добро Есте Живите Зело Земля
И Иже Како Люди Мыслите Нашь Онъ Покой
Рцы Слово Твердо Укъ Фърътъ Херъ Цы Черве Шта Ъра Юсь Яти.

Глаголь Добро – говори, делай добро.
Помните у Пушкина: «Глаголом жечь сердца людей».
Глагол – это и слово, и дело одновременно.
Говорю – значит делаю. И делаю добро.
http://www.dunmers.com

▲ Предисловие

Рассмотрим последовательность разработки приложений на Глаголе.

Свои программы лучше создавать в Оболочке Глагола или при помощи текстового редактора, поддерживающего кодировку УниКод (UTF16 = UCS2-Little Endian), например, в русском редакторе Булычова О.И. и Егорова Н.А. Bred3 (брэд3) с модулем расцветки синтаксиса Колорер-5 от Игоря Русских (скачать архив
Bred3_plugin_colorer5_Glagol-ARM-Mod-Ob2-ob7-cp-Strannik.rar),

а также в безплатных текстовых редакторах Notepad++ (нотепад++) или SciTE (скайт). Подробнее о Total Commander и редакторе Bred3 изложено на странице Среда разработки приложений на Глаголе [для Windows].

Исходные тексты своих приложений лучше хранить в папке \Глагол\Приложения\Свои\. Преобразователь Глагола (ПГ.exe) будет переводить исходные тексты приложений в машинные команды и помещать их в промежуточные .obj файлы в папке \Глагол\Приложения\Свои\Код\, а редактор связей из полученных .obj файлов будет собирать окончательный EXE-файл. Подробнее о создании приложений можно ознакомиться на странице ответов на часто задаваемые вопросы.

Ниже мы разберём несколько небольших примеров приложений Windows.

Однако, если же вы будете переносить исходные тексты примеров из этого файла Azbuka.htm в текстовый файл при помощи буфера обмена, то в полученном текстовом файле могут оказаться особые знаки (неделимые пробелы), на которые ПГ будет выдавать ошибку. Для успешной работы необходимо будет подправить текстовый файл, удалив или заменив эти знаки.

Теперь приступим к написанию приложений.

▲ А) Здравствуйте!

Наше первое приложение будет всего лишь выводить на экран фразу "Привѣтъ, мiръ!".

Перейдём в папку \Глагол\Приложения\Оболочка\, где храняться исходные тексты и EXE-файлы приложения Оболочка и посмотрим файл "\Глагол\Приложения\Оболочка\Привет.отд":

ОТДЕЛ Привет+;
ИСПОЛЬЗУЕТ
  Вывод ИЗ "...\Отделы\Обмен\";
УКАЗ
  Вывод.Цепь("Привѣтъ, мiръ!")
КОН Привет.

В этом файле 1-я строка

ОТДЕЛ Привет+;

объявляет название отдела приложения. Строка

ИСПОЛЬЗУЕТ
  Вывод ИЗ "...\Отделы\Обмен\";

разрешает использовать в нашем отделе переменные, задачи и другие понятия из отдела с именем Вывод. Причём, исходный текст этого отдела Преобразователь Глагола будет искать в файле "...\Отделы\Обмен\Вывод.отд". Следующая строка

УКАЗ

  Вывод.Цепь("Привѣтъ, мiръ!")

является единственным указанием в нашем отделе. По этому указанию вызывается задача Цепь для вывода на экран цепочки знаков "Привѣтъ, мiръ!" (слово Вывод, стоящее до точки, указывает на используемый отдел, из которого берётся задача Цепь). Последняя строка

КОН Привет.

Теперь нужно получить исполняемый файл приложения "\Глагол\Приложения\Оболочка\Привет.отд", т.е. преобразовать исходные тексты всех используемых (явно и неявно) отделов нашего приложения в машинный код и собрать из него исполняемый EXE-файл. Для этого создаём в текущей папке \Оболочка\ (или берём из неё) командный файл "\Глагол\Приложения\Оболочка\Построить.bat" следующего содержания:

@Echo ON
rem Для вызова Построить.bat [приложение консоли Windows или в Консольном Окне] необходимо, чтобы:
rem %1        - имя приложения (без расширения .отд)

rem %slujput% - Путь к папке \Глагол\Службы\ относительно текущей папки \Оболочка с приложением %1
set slujput=..\..\Службы
rem %tekput%  - Путь к папке \Оболочка с приложением %1 из папки \Глагол\Службы\
set tekput=..\Приложения\Оболочка
pause;
call %slujput%\Построить.bat %1

c:\Глагол\Приложения\Оболочка> Построить Привет

Если при преобразовании и сборке не будет выявлено никаких ошибок, то после окончания работы этого командного файла будет создан файл "Привет.exe".

Если запустить этот файл в проводнике Windows или в Total Commander, то можно и не успеть увидеть результата его работы. Эту трудность можно разрешить путём использования системной консольной оболочки:
    — в Win NT/XP/7/8 перейдите в Пуск>Выполнить>cmd или запустите файл C:\Windows\System32\CMD.exe;
    — в Win 9x вызовите 'Сеанс MS-DOS'
и перейдите в папку с файлом "Привет.exe" по команде

>cd \Глагол\Приложения\Оболочка

Теперь запустите EXE-приложение Привет.exe по команде

c:\Глагол\Приложения\Оболочка> Привет

После запуска приложения на экране появится слово "Привѣтъ, мiръ!". Всё, первое приложение создано.

Запуск приложения Привет.exe в консоле Windows — c:\Глагол\Приложения\Оболочка> Привет

Открытие, редактирование и запуск приложения Привет.отд в Оболочке Глагола в Графическом Окне

Открытие, редактирование и запуск приложения Привет.отд в Оболочке Глагола в Консольном (текстовом) Окне

▲ Б) А сколько Вам лет?

Теперь напишем приложение "\Глагол\Приложения\Оболочка\Возраст.отд", которое будет выводить текст уже в зависимости от значения некоторой переменной. Для этого в приложении будет использоваться указание ВЫБРАТЬ п ИЗ…КОН.

Объявляем название отдела приложения:

ОТДЕЛ Возраст+;

Указываем используемые отделы. В нашем случае используется только отдел "Вывод", который нам будет нужен для вывода на экран текста:

ИСПОЛЬЗУЕТ
  Вывод ИЗ "...\Отделы\Обмен\";

Объявляем постоянную, общую для всего отдела:

ПОСТ
  нынешнийГод = 2006;

Объявляем задачу Положение, на вход которой поступает целое значение в переменной годРождения:

ЗАДАЧА Положение(годРождения:ЦЕЛ);

В задаче объявляем переменную положение для хранения цепочки из 7 знаков:

ПЕР
  положение:РЯД 7 ИЗ ЗНАК;

И переменную возраст для хранения целого числа:

  возраст:ЦЕЛ;

Начинаем исполняемые указания данной задачи:

УКАЗ

Сначала вычислим возраст:

  возраст:=нынешнийГод - годРождения;

В одной старинной рукописи приводится такое описание:

ДЕТИЩЬДОСЕДМЬЛЕТЪ
ОТРОЧАДОДВОЮСЕДМИЦЬЛЕТЪ
ОТРОКЪДОТРЕХЪСЕДМИЦЬ
ЮНОШАДОЧЕТЫРЕХЪСЕДМИЦЬ
МУЖЬДООСМИСЕДМИЦЬ
ИОТТОЛЕСТАРЕЦЬ

При помощи указания ВЫБРАТЬ п ИЗ выполним соответствующее присваивание переменной положение:

  ВЫБРАТЬ возраст ИЗ
  |   0 .. 7*1 - 1: положение:="дитя"
  | 7*1 .. 7*2 - 1: положение:="отрок"
  | 7*2 .. 7*3 - 1: положение:="юноша"
  | 7*3 .. 7*8 - 1: положение:="муж"
  | 60,70,80,90:  положение:="юбиляр"

Если текущее значение переменной возраст не совпадает ни с одним из заранее заданных наборов значений, то выполняется особое присваивание:

  ИНАЧЕ
    положение:="старец"

  КОН;

Выводим на экран с новой строки такую фразу: "мужчина N года рождения -", где N будет текущим значением переменной годРождения. Для этого мы воспользуемся задачей ЧЦел из отдела Вывод. Эта задача может выводить на экран до четырёх значений целых переменных вместе с сопровождающим их текстом.

  Вывод.ЧЦел("^мужчина %d года рождения - ",годРождения,0,0,0);
  (* Пояснение: при записи текста в поток (в т.ч. на экран)
   * знак ^ обозначает переход на новую строку и сброс данных *) 

После этого выводим на экран значение переменной положение:

  Вывод.Цепь(положение)

Объявляем конец задачи Положение словесной закрывающей скобкой КОН с именем задачи (и точкой с запятой):

КОН Положение;

Начинаем последовательность указаний, выполняющихся при запуске приложения:

УКАЗ

Последовательно вызываем задачу Положение с разными значениями для входной переменной годРождения:

  Положение(1917);
  Положение(1991);
  Положение(2004)

КОН Возраст.

В итоге в файле "\Глагол\Приложения\Оболочка\Возраст.отд" мы должны получить текст следующего содержания:

ОТДЕЛ Возраст+;

ИСПОЛЬЗУЕТ
  Вывод ИЗ "...\Отделы\Обмен\";

ПОСТ
  нынешнийГод = 2006;

ЗАДАЧА Положение(годРождения:ЦЕЛ);
ПЕР
  положение:РЯД 7 ИЗ ЗНАК;
  возраст:ЦЕЛ;
УКАЗ
  возраст:=нынешнийГод - годРождения;
  ВЫБРАТЬ возраст ИЗ
  |   0 .. 7*1 - 1: положение:="дитя"
  | 7*1 .. 7*2 - 1: положение:="отрок"
  | 7*2 .. 7*3 - 1: положение:="юноша"
  | 7*3 .. 7*8 - 1: положение:="муж"
  | 60,70,80,90:  положение:="юбиляр"
  ИНАЧЕ
    положение:="старец"
  КОН;
  Вывод.ЧЦел("^мужчина %d года рождения - ",годРождения,0,0,0);
  (* Пояснение: при записи текста в поток (в т.ч. на экран)
   * знак ^ обозначает переход на новую строку и сброс данных *) 
  Вывод.Цепь(положение)
КОН Положение;

УКАЗ
  Положение(1917);
  Положение(1991);
  Положение(2004)
КОН Возраст.

Чтобы получить исполняемый EXE-файл этого примера, просто добавьте в конец командного файла "\Глагол\Приложения\Оболочка\Построить.bat" следующую строчку:

call %slujput%\Построить.bat Возраст

После запуска приложения на экране должно появиться:

В 2006 году:
мужчина 1917 года рождения - старец
мужчина 1991 года рождения - юноша
мужчина 2004 года рождения - дитя

Открытие и редактирование приложения Возраст.отд в Оболочке Глагола в Графическом Окне

Тоже самое в диспетчере Файлов и Архивов Рошаля ФАР (3-я версия, 2014г.) с ФарКолорер-5 Игоря Русских

Теперь у вас достаточно опыта, чтобы самостоятельно разбираться в примерах из папки \Глагол\Приложения\Иное\.

▲ В) Время, вперёд!

Приступим к рассмотрению последнего примера. Это приложение будет взаимодействовать с человеком не через командную строку, а через обычные экранные кнопки. Нажатие на эти кнопки можно осуществлять как при помощи мышки, так и при помощи клавиатуры (клавиши "пробел" и "ввод", если кнопка принимает ввод). Стоит отметить, что это приложение можно выполнять и без файловой оболочки, т.к. оно работает в Графическом Окне Windows и заканчивает свою работу не сразу после запуска, а только по команде пользователя.

Наше приложение является секундомером. Вот так оно будет выглядеть в работе:

Запуск приложения Секундомер в Графическом Окне:

Запуск приложения Секундомер в Консольном Окне:

Рассмотрим строение данных этого приложения. На экране определяется рабочее поле, а на поле выделяются наделы, в которые можно вводить и выводить данные. Координаты левого верхнего угла поля отсчитываются относительно левого верхнего угла экрана, а координаты наделов — от левого верхнего угла поля. Причем координата X увеличивается справа налево, а координата Y — сверху вниз. В нашем примере используются только два вида наделов: текстовая метка и экранная кнопка. Метка служит для вывода на экран однострочного текста, а кнопка — для передачи в приложение действий от человека.

Объявляем название отдела нашего приложения Секундомер и названия отделов, которые он использует:

ОТДЕЛ Секундомер+;

ИСПОЛЬЗУЕТ
  Ввод   ИЗ "...\Отделы\Обмен\",
  ОС     ИЗ "...\Отделы\Обмен\",
  Поле   ИЗ "...\Отделы\Поле\",
  Надел  ИЗ "...\Отделы\Поле\",
  Метка  ИЗ "...\Отделы\Поле\",
  Кнопка ИЗ "...\Отделы\Поле\";

Объявляем постоянные, соответствующие номерам действий, которые вырабатываются при нажатии соответствующих кнопок:

ПОСТ           (* действия кнопок [Пуск], [Стоп], [Сброс], [Выход] *)
  дПуск  = 1;
  дСтоп  = 2;
  дСброс = 3;
  дВыход = 4;

Заводим логическую переменную, которая будет принимать значение ВКЛ, если секундомер в данный момент ведёт измерения:

ПЕР
  идётИзмерение:КЛЮЧ;  (* ВКЛ, если идёт измерение времени *)

И целую переменную, которая будет хранить измеренный промежуток времени:

  измеренноеВремя:ЦЕЛ; (* промежуток времени в мс          *)

Далее объявляем задачу, которая выводит через экранную метку "мВремя" обновлённые показания времени в привычном для человека виде (часы:минуты:секунды.сотые):

ЗАДАЧА ОбновитьПоказания(номерЧасов:ЦЕЛ);
(* обновить показания секундомера *)
ПЕР
  сотые,секунды,минуты,часы:ЦЕЛ;
  сейчас:ЦЕЛ;
  прошлоВремени:ЦЕЛ;
УКАЗ
  сейчас:=ОС.Время();
  прошлоВремени:=сейчас - моментОбновления;
  моментОбновления:=сейчас;
  ЕСЛИ идётИзмерение ТО
    УВЕЛИЧИТЬ(измеренноеВремя,прошлоВремени)
  КОН;
  сотые:=измеренноеВремя ДЕЛИТЬ 10;
  секунды:=сотые ДЕЛИТЬ 100;
  минуты:=секунды ДЕЛИТЬ 60;
  часы:=минуты ДЕЛИТЬ 60;
  Записка.ИзЧЦел(
  зВремя,"%.2d:%.2d:%.2d.%.2d",
    часы,минуты ОСТАТОК 60,
        секунды ОСТАТОК 60,
          сотые ОСТАТОК 100
                )
КОН ОбновитьПоказания;

Следующая задача будет принимать и обрабатывать действия пользователя в экранном поле поле. Причем посылка от пользователя на входе задачи содержит или действие от экранной кнопки (1,2,3,4) или код клавиши клавиатуры (1,2,3,4) или данные о перемещении мышки:

ЗАДАЧА Приём(поле:Поле.Доступ; посылка+:Ввод.Посылка);
(* получить и обработать управляющие послания от пользователя *)
УКАЗ

Разные виды переменной посылка имеют разные наборы данных. Поэтому для разных видов этой переменной мы будем выполнять разную последовательность указаний. Для переменной посылка вида Кнопка.Посылка:

  ДЛЯ посылка ВИДА
  | Кнопка.Посылка:

известно, что набор данных содержит переменную действие. По значению этой переменной мы определим, какую кнопку нажал пользователь в данный момент, и выполним соответствующее указание. По нажатию на кнопку "Пуск" включаем измерение времени, по кнопке "Стоп" отключаем измерение, по кнопке "Сброс" обнуляем измеренное время, а по кнопке "Выход" сообщаем главной задаче о желании пользователя выйти из приложения:

      ВЫБРАТЬ посылка.кнопка.действие ИЗ (* действия кнопок [Пуск],[Стоп],[Сброс],[Выход] *)
      | дПуск:  идётИзмерение:=ВКЛ
      | дСтоп:  идётИзмерение:=ОТКЛ
      | дСброс: измеренноеВремя:=0
      | дВыход: поле.состояние:=Поле.сДалее  (* встроенные состояния поля (<= 0): *)
      КОН

Учитывая, что в наборе посылка вида Ввод.ОтКлавиш есть переменные "код", "упрКнопки", мы сможем выполнить следующее указание: при нажатии на клавишу "Esc" или клавишу "X" совместно с "Alt" сообщим через состояние поля, что требуется выход из приложения:

  | Ввод.ОтКлавиш:
      ЕСЛИ посылка.упрАльт И (посылка.код = 58H) (* Alt+'X' *)
         ИЛИ
          (посылка.код = 1BH)                    (* Esc     *)
      ТО
        поле.состояние:=Поле.сДалее  (* встроенные состояния поля (<= 0): *)
      КОН

Так как нам не нужно, чтобы приложение аварийно завершало свою работу при получении посылки вида, отличного от Кнопка.Посылка и Ввод.ОтКлавиш, то отработаем это условие как пустую последовательность указаний:

  ИНАЧЕ
  КОН

Заканчиваем задачу Приём и начинаем задачу Главная.

КОН Приём;

ЗАДАЧА Главная;

Определяем в задаче Главная переменные для поля (экрана), наделов (кнопок), списка наделов и переменную для хранения момента времени, в который произошло обновление показаний секундомера:

ПЕР
  поле:Поле.Доступ;                             (* рабочее поле экрана     *)
  подложка:Подложка.Доступ;                     (* подложка поля           *)
  кнСтоп,кнПуск,кнСброс,кнВыход:Кнопка.Доступ; (* управляющие кнопки      *)
  черта1,черта2:Черта.Доступ;                   (* разделительные чёрточки *)
  часы:ЦЕЛ;

Затем в задаче Главная объявляем подзадачу СоздатьПоле, в которой сначала создаём соответствующие наделы с заданными координатами:

  ЗАДАЧА СоздатьПоле;     (* создаёт рабочее поле экрана с кнопками-наделами *)
  УКАЗ                                                 (* создаём поле *)
                                  (* задача Приём *)
    поле:=Поле.Создать(0,0,8,17,ПУСТО,ОТКЛ,Приём);
                                                     (* создаём наделы *)
    подложка:=Подложка.Создать(0,0,0,0,"");
    зВремя:=Записка.Создать(1,3,1,11,"00:00:00.00");
    черта1:=Черта.Создать(2,0,1,0);
    кнПуск:=Кнопка.Создать(3,2,"[~Пуск]",дПуск,ВКЛ);
    кнСтоп:=Кнопка.Создать(3,9,"[~Стоп]",дСтоп,ВКЛ);
    кнСброс:=Кнопка.Создать(4,4,"[ С~брос ]",дСброс,ВКЛ);
    черта2:=Черта.Создать(5,0,1,0);
    кнВыход:=Кнопка.Создать(6,4,"[ ~Выход ]",дВыход,ВКЛ);

Далее заносим эти наделы в список получения ввода. Этот список определяет порядок обхода наделов при нажатии пользователем клавиши "Tab". В начале работы приложения первому наделу из этого списка, вид которого способен воспринимать ввод (в нашем случае это только кнопки, а не метки), будет предоставлена возможность получать ввод от человека.

                            (* добавляем наделы в порядке получения ввода *)
    Поле.ДобавитьНадел(поле,подложка);
    Поле.ДобавитьНадел(поле,зВремя);
    Поле.ДобавитьНадел(поле,черта1);
    Поле.ДобавитьНадел(поле,кнПуск);
    Поле.ДобавитьНадел(поле,кнСтоп);
    Поле.ДобавитьНадел(поле,кнСброс);
    Поле.ДобавитьНадел(поле,черта2);
    Поле.ДобавитьНадел(поле,кнВыход)
  КОН СоздатьПоле;

Далее начинается последовательность указаний задачи Главная. В начале мы проводим следующие подготовительные действия: выставляем начальные значения рабочих переменных, вызываем подзадачу для создания поля, рисуем поле со всеми наделами:

УКАЗ                                       (* задача ОбновитьПоказания *)
  Окно.Графическое("Секундомер","Lucida Console",30,ОбновитьПоказания);
(*
  Окно.Текстовое(ОбновитьПоказания);
 *)
  СоздатьПоле;
  Поле.ОкноНаВсёПоле(поле);
  Поле.Рисовать(поле);
  часы:=Окно.СоздатьЧасы(1,100); (* обновляем показания через 100мс *)
  Окно.Показать;

И, наконец, цикл, который будет выполняться всё основное время работы приложения (пока состояние поля будет рабочим):

                                   (* проверяем и обрабатываем ввод от человека *)
  ПОКА поле.состояние = Поле.сРабота ВЫП  (* встроенные состояния поля (<= 0): *)
    Поле.Проверить(поле)
  КОН;
  Окно.УдалитьЧасы(часы)

Заканчиваем задачу Главная, затем указываем на её выполнение при запуске приложения (после УКАЗ) и завершаем отдел "Секундомер":

КОН Главная;

УКАЗ
  измеренноеВремя:=0;
  идётИзмерение:=ОТКЛ;
  Главная
КОН Секундомер.

Полный текст данного приложения см. ниже или в "\Глагол\Приложения\Иное\Секундомер.отд":

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                        ОТДЕЛ Секундомер+;
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(* НАЗНАЧЕНИЕ: пример использования наделов и времени                         *)
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ИСПОЛЬЗУЕТ
  ОС       ИЗ "...\Отделы\Обмен\",   (* для считывания времени *)
  Окно     ИЗ "...\Отделы\Обмен\",
  Ввод     ИЗ "...\Отделы\Обмен\",
  Поле     ИЗ "...\Отделы\Поле\",
  Подложка ИЗ "...\Отделы\Поле\",
  Записка  ИЗ "...\Отделы\Поле\",
  Кнопка   ИЗ "...\Отделы\Поле\",
  Черта    ИЗ "...\Отделы\Поле\";

ПОСТ           (* действия кнопок [Пуск],[Стоп],[Сброс],[Выход] *)
  дПуск  = 1;
  дСтоп  = 2;
  дСброс = 3;
  дВыход = 4;

ПЕР
  идётИзмерение:КЛЮЧ;    (* ВКЛ, если идёт измерение времени  *)
  измеренноеВремя:ЦЕЛ;   (* промежуток времени в мс           *)
  моментОбновления:ЦЕЛ;  (* показаний                         *)
  зВремя:Записка.Доступ; (* записка с показаниями секундомера *)

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОбновитьПоказания(номерЧасов:ЦЕЛ);
(* обновить показания секундомера *)
ПЕР
  сотые,секунды,минуты,часы:ЦЕЛ;
  сейчас:ЦЕЛ;
  прошлоВремени:ЦЕЛ;
УКАЗ
  сейчас:=ОС.Время();
  прошлоВремени:=сейчас - моментОбновления;
  моментОбновления:=сейчас;
  ЕСЛИ идётИзмерение ТО
    УВЕЛИЧИТЬ(измеренноеВремя,прошлоВремени)
  КОН;
  сотые:=измеренноеВремя ДЕЛИТЬ 10;
  секунды:=сотые ДЕЛИТЬ 100;
  минуты:=секунды ДЕЛИТЬ 60;
  часы:=минуты ДЕЛИТЬ 60;
  Записка.ИзЧЦел(
  зВремя,"%.2d:%.2d:%.2d.%.2d",
    часы,минуты ОСТАТОК 60,
        секунды ОСТАТОК 60,
          сотые ОСТАТОК 100
                )
КОН ОбновитьПоказания;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Приём(поле:Поле.Доступ; посылка+:Ввод.Посылка);
(* получить и обработать управляющие послания *)
УКАЗ
  ДЛЯ посылка ВИДА
  | Кнопка.Посылка:
      ВЫБРАТЬ посылка.кнопка.действие ИЗ (* действия кнопок [Пуск],[Стоп],[Сброс],[Выход] *)
      | дПуск:  идётИзмерение:=ВКЛ
      | дСтоп:  идётИзмерение:=ОТКЛ
      | дСброс: измеренноеВремя:=0
      | дВыход: поле.состояние:=Поле.сДалее  (* встроенные состояния поля (<= 0): *)
      КОН
  | Ввод.ОтКлавиш:
      ЕСЛИ посылка.упрАльт И (посылка.код = 58H) (* Alt+'X' *)
         ИЛИ
          (посылка.код = 1BH)                    (* Esc     *)
      ТО
        поле.состояние:=Поле.сДалее  (* встроенные состояния поля (<= 0): *)
      КОН
  ИНАЧЕ
  КОН
КОН Приём;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Главная;
ПЕР
  поле:Поле.Доступ;                             (* рабочее поле экрана   *)
  подложка:Подложка.Доступ;                     (* подложка поля         *)
  кнСтоп,кнПуск,кнСброс,кнВыход:Кнопка.Доступ; (* управляющие кнопки    *)
  черта1,черта2:Черта.Доступ;                   (* разделительные черты  *)
  часы:ЦЕЛ;

  (*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
  ЗАДАЧА СоздатьПоле;     (* создаёт рабочее поле экрана с кнопками-наделами *)
  УКАЗ                                           (* создаём поле экрана *) 
                                  (* задача Приём *)
    поле:=Поле.Создать(0,0,8,17,ПУСТО,ОТКЛ,Приём);
                                                     (* создаём наделы *)
    подложка:=Подложка.Создать(0,0,0,0,"");
    зВремя:=Записка.Создать(1,3,1,11,"00:00:00.00");
    черта1:=Черта.Создать(2,0,1,0);
    кнПуск:=Кнопка.Создать(3,2,"[~Пуск]",дПуск,ВКЛ);
    кнСтоп:=Кнопка.Создать(3,9,"[~Стоп]",дСтоп,ВКЛ);
    кнСброс:=Кнопка.Создать(4,4,"[ С~брос ]",дСброс,ВКЛ);
    черта2:=Черта.Создать(5,0,1,0);
    кнВыход:=Кнопка.Создать(6,4,"[ ~Выход ]",дВыход,ВКЛ);
                            (* добавляем наделы в порядке получения ввода *)
    Поле.ДобавитьНадел(поле,подложка);
    Поле.ДобавитьНадел(поле,зВремя);
    Поле.ДобавитьНадел(поле,черта1);
    Поле.ДобавитьНадел(поле,кнПуск);
    Поле.ДобавитьНадел(поле,кнСтоп);
    Поле.ДобавитьНадел(поле,кнСброс);
    Поле.ДобавитьНадел(поле,черта2);
    Поле.ДобавитьНадел(поле,кнВыход)
  КОН СоздатьПоле;

УКАЗ                                       (* задача ОбновитьПоказания *)
  Окно.Графическое("Секундомер","Lucida Console",30,ОбновитьПоказания);
(*
  Окно.Текстовое(ОбновитьПоказания);
 *)
  СоздатьПоле;
  Поле.ОкноНаВсёПоле(поле);
  Поле.Рисовать(поле);
  часы:=Окно.СоздатьЧасы(1,100); (* обновляем показания через 100мс *)
  Окно.Показать;
                                  (* проверяем и обрабатываем ввод от человека *)
  ПОКА поле.состояние = Поле.сРабота ВЫП  (* встроенные состояния поля (<= 0): *)
    Поле.Проверить(поле)
  КОН;
  Окно.УдалитьЧасы(часы)
КОН Главная;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
УКАЗ
  измеренноеВремя:=0;
  идётИзмерение:=ОТКЛ;
  Главная
КОН Секундомер. 

Преобразование приложения Секундомер.отд на Глаголе в исполняемый EXE-файл в консоле Windows

Для улучшения рабочего вида секундомера в Win NT необходимо в свойствах ярлыка файла Секундомер.exe на закладке "Расположение" установить "Размер" на ширину 17 и высоту 11. Также можно увеличить и размер шрифта.

Отметим, что в примерах игр (папка \Глагол\Приложения\Игры\) взаимодействие приложения с человеком организовано точно так же, как и в разобранном выше примере.

Азъ Буки Веде Глаголь Добро Есте Живите Зело Земля
И Иже Како Люди Мыслите Нашь Онъ Покой
Рцы Слово Твердо Укъ Фърътъ Херъ Цы Черве Шта Ъра Юсь Яти.

Глаголь Добро – говори, делай добро.
Помните у Пушкина: «Глаголом жечь сердца людей».
Глагол – это и слово, и дело одновременно.
Говорю – значит делаю. И делаю добро.
http://www.dunmers.com