(*~\Глагол\Отделы\ЧисАн\64\к\Ряд\ВводВывод\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                                 ОТДЕЛ крМатрВВ;
(*============================================================================*
 * НАЗНАЧЕНИЕ: (ввод из файла)/(вывод в файл) и печать на экран матриц
 *                      комплексных чисел (64 разряда) в виде ряда из 2-х вещ.
 *============================================================================*)

ИСПОЛЬЗУЕТ 
 дМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\д\",

крМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к\Ряд\",  
крМатрица ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к\Ряд\",

  ИзФайла ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
   ВФайл  ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
  НаЭкран ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\";

ВИД
(*
основной Вид отдела:
                     Вид- = РЯД ИЗ крВектор.Вид; (* матрица из комплексных чисел в виде ряда из 2-х вещ. *)
                 или
                     Вид- = РЯД ИЗ
                            РЯД ИЗ крМатем.Вид;  (* матрица из комплексных чисел в виде ряда из 2-х вещ. *)
  Доступ- = ДОСТУП К Вид;               (* доступ к матрице из комплексных чисел в виде ряда из 2-х вещ. *)
*)
        (* вид Вещ - это удвоенная точность 64 разряда (16 десятичных знаков) *)
  Вещ = дМатем.Вещ;                   (* локально *)


(*-оооооооооооооо- опережающие определения/заготовки задач -ооооооооооооооооо-*)


ЗАДАЧА^ ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;

ЗАДАЧА^ изФайла-(потокЧтеД:ИзФайла.ДкПотоку):крМатрица.Доступ;

ЗАДАЧА^ наЭкран-(описание-:ЦЕПЬ;
                         кМатр- :крМатрица.Вид);

ЗАДАЧА^ вФайл-(выходФайл:ВФайл.ДкПотоку;
                       описание-:ЦЕПЬ;
                         кМатр- :крМатрица.Вид);


(*=рррррррррррррррррррррррр= реализация задач =рррррррррррррррррррррррррррррр=*)


(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;
(*
 * Цель:  если возможно, то открыть поток на чтение, иначе АВОСТ
 *----------------------------------------------------------------------------*
 * До:    <имяФайла> - имя считываемого файла
 * Ответ: открытый на чтение поток (ДОСТУП к Потоку)
 *)
ПЕР
       потокД:ИзФайла.ДкПотоку;
УКАЗ
       потокД:=ИзФайла.Открыть(имяФайла);
  ЕСЛИ
       потокД = ПУСТО
  ТО
    НаЭкран.ВсяЦепь('^Файл "');
    НаЭкран.ВсяЦепь(имяФайла);
    НаЭкран.ВсяЦепь('" не найден.^');
    СТОП(1) 
  КОН;
          потокД.цВидЗнаков:=ИзФайла.знУни;
  ВОЗВРАТ потокД
КОН ОткрытиеФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА изФайла-(потокЧтеД:ИзФайла.ДкПотоку):крМатрица.Доступ;
(*
 * Цель: прочитать из вх.потока размер комплексной матрицы (строк, столбцов)
 *       создать матрицу комплексных чисел в виде ряда из 2-х вещ.
 *       и заполнить её данными из этого потока
 *----------------------------------------------------------------------------*
 * До:    <потокЧтеД> - открытый на чтение поток - входной файл
 * Ответ: доступ к выходной матрице комплексных чисел в виде ряда из 2-х вещ.
 *)
ПЕР
  i,j,строк,столбцов:ЦЕЛ;
  дT,мT:Вещ;
          кВыхМатД:крМатрица.Доступ;
УКАЗ
                   строк:=         ИзФайла.Цел32(потокЧтеД);
                         столбцов:=ИзФайла.Цел32(потокЧтеД);
  СОЗДАТЬ(кВыхМатД,строк,столбцов);

  ОТ i:=0 ДО строк-1 ВЫП
    ОТ j:=0 ДО столбцов-1 ВЫП
                               дT:=ИзФайла.Вещ64(потокЧтеД);
                               мT:=ИзФайла.Вещ64(потокЧтеД);
      крМатем.алгебрВид(дT,мT,кВыхМатД[i,j])
    КОН 
  КОН;
  ВОЗВРАТ кВыхМатД
КОН изФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкран-(описание-:ЦЕПЬ;
                        кМатр- :крМатрица.Вид);
(*
 * Цель: вывести на экран содержимое комплексной матрицы <кМатр> 
 *----------------------------------------------------------------------------*
 * До:  <описание> - описатель печати элемента матрицы из компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)"
 *        <кМатр>  - прямоугольная комплексная матрица NxN чисел в виде ряда из 2-х вещ.
 *)
ПЕР
  i,j:ЦЕЛ;
УКАЗ
  ОТ i:=0 ДО РАЗМЕР(кМатр,0)-1 ВЫП
    ОТ j:=0 ДО РАЗМЕР(кМатр,1)-1 ВЫП
      НаЭкран.Вещ4числа(
                            описание,            (* должно иметь (%23.17f; %23.17f) *)
                                     кМатр[i,j][0],
                                     кМатр[i,j][1],0,0)
    КОН;
               (* переход на новую строку для печати следующей строки матрицы *)
      НаЭкран.ВсяЦепь('^')
  КОН
КОН наЭкран;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА вФайл-(выходФайл:ВФайл.ДкПотоку;
                      описание-:ЦЕПЬ;
                        кМатр- :крМатрица.Вид);
(*
 * Цель: записать в выходной файл содержимое комплексной матрицы <кМатр> 
 *----------------------------------------------------------------------------*
 * До: <выходФайл> - открытый для записи поток - выходной файл
 *      <описание> - описатель печати элемента матрицы из компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)"
 *      <кМатр>    - прямоугольная комплексная матрица NxN чисел в виде ряда из 2-х вещ.
 *)
ПЕР
  i,j:ЦЕЛ;
УКАЗ
  ОТ i:=0 ДО РАЗМЕР(кМатр,0)-1 ВЫП
    ОТ j:=0 ДО РАЗМЕР(кМатр,1)-1 ВЫП
      ВФайл.Вещ4числа(выходФайл,
                            описание,            (* должно иметь (%23.17f; %23.17f) *)
                                      кМатр[i,j][0],
                                      кМатр[i,j][1],0,0)
    КОН;
               (* переход на новую строку для печати следующей строки матрицы *)
      ВФайл.ЦепьЗнаков(выходФайл,'^')
  КОН
КОН вФайл;
 
КОН крМатрВВ.
