(*~\Глагол\Отделы\Оболочка\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                           ОТДЕЛ Справка;
(*============================================================================* 
 * НАЗНАЧЕНИЕ:
 *             работа с CHM-справочниками средствами Операционной Системы (ОС) Windows 
 * ПРИМЕЧАНИЯ:
 *             вызов ОС происходит через Spravka.DLL - в папке с приложением Оболочка.exe 
 *============================================================================*)

ИСПОЛЬЗУЕТ
(*           Глагол\              *)
 оЦепи    ИЗ "..\..\Отделы\Иное\";

ПЕР
                   (* полное имя файла CHM-справочника = Глагол.chm в папке с приложением Оболочка.exe *)
  имяФ:ЦЕПЬ[300];

                (* используемые задачи из DLL-библиотеки Spravka.dll *)

ЗАДАЧА Kluch (имяФ-,ключ-:ЦЕПЬ);      ВЫЗОВ "Kluch"  ИЗ "Spravka.dll"; (* ищется в PATH (путь) или берётся из папки с приложением Оболочка.exe *)
ЗАДАЧА Nomer (имяФ-:ЦЕПЬ; номер:ЦЕЛ); ВЫЗОВ "Nomer"  ИЗ "Spravka.dll";
ЗАДАЧА Razdel(имяФРаздел-:ЦЕПЬ);      ВЫЗОВ "Razdel" ИЗ "Spravka.dll";

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Ключ-(ключ-:ЦЕПЬ);         (* Цель:  поиск разделов по ключевому слову *)
УКАЗ
  Kluch(имяФ,ключ)
КОН Ключ;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Номер-(номер:ЦЕЛ);                (* Цель: поиск раздела по его номеру *)
УКАЗ
  Nomer(имяФ, номер)
КОН Номер;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Раздел-(раздел-:ЦЕПЬ);        (* Цель:  поиск раздела по его htm имени *)
            (* раздел = Obolochka.htm *)
ПЕР
  имяФРаздел:ЦЕПЬ[300];             (* полное имя htm-файла в CHM-справочнике *)
УКАЗ
  СПИСАТЬ(имяФ,имяФРаздел);
            (* имяФРаздел = "Глагол.chm" *)
  оЦепи.ДобавитьВКонец(имяФРаздел,"::/");
            (* имяФРаздел = "Глагол.chm::/" *)
  оЦепи.ДобавитьВКонец(имяФРаздел,раздел);
          (* например,
                       имяФРаздел = "Глагол.chm::/Obolochka.htm"
                  или 
                       имяФРаздел = "Глагол.chm::/Введение.htm>okno"
           *)
  Razdel(имяФРаздел) (* открыть окно со справкой по рус.ЯП Глагол из Оболочка.exe
                         с раздела  "Глагол.chm::/Obolochka.htm"              *)
КОН Раздел;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА Подготовить-(имяHTMфайла-:ЦЕПЬ);
(*
 * Цель:  подготовить вызовы внешних задач
 * До:   <имяHTMфайла> - полное имя htm-файла в CHM-справочнике
 *)
УКАЗ
  СПИСАТЬ(имяHTMфайла,Справка.имяФ)
                   (* Справка.имяФ - локальное для этого отдела Справка *)
КОН Подготовить;

КОН Справка.
