(*~\Глагол\Отделы\Поле\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                            ОТДЕЛ Записка;
(*============================================================================* 
 * НАЗНАЧЕНИЕ: изменяемый многострочный текст
 *============================================================================*)

ИСПОЛЬЗУЕТ 
  Надел,
  Поле,
        (*  \Глагол\               *)
  Ввод    ИЗ "..\..\Отделы\Обмен\",
  Окно    ИЗ "..\..\Отделы\Обмен\",
  Текст   ИЗ "..\..\Отделы\Обмен\";

ВИД
  Доступ- = ДОСТУП К Вид;   (* Записка.Доступ <- Надел.Доступ <- Рамка.Доступ *)
                     Вид- =
  НАБОР (Надел.Вид)         (* Записка.Вид    <- Надел.Вид    <- Рамка.Вид    *)
    текст:ЦЕПЬ[200]
  КОН;

(*-----------------------------------------локальная ЗАДАЧА-------------------*)
ЗАДАЧА                                                         (*(Записка.Вид)*)
       Отрисовка(запискаД:Записка.Доступ);
УКАЗ
   Надел.Очистить(запискаД);
  Окно.ЦепьЗнаков(запискаД.вс,
                  запискаД.лк,
                  запискаД.нс,
                  запискаД.пк,
                  запискаД.текст)
КОН Отрисовка;
(*-----------------------------------------локальная ЗАДАЧА-------------------*)
ЗАДАЧА                                           (* (Записка.Вид <- Надел.Вид)*)(* приём посылок из вне (снаружи) *)
       Приём(наделД:Надел.Доступ;
           посылка+:Ввод.нПосылка); (* = Пустой.Вид; - абстрактный опорный набор *)
УКАЗ
                             (* анализ многоформия (полиморфизма) у <посылка> = Пустой.Вид *)
  ДЛЯ      посылка ВИДА
  | Поле.нОтрисовка: Отрисовка(
                                                             (* преобразование
                               наделД                 из Надел.Доступ в
                                      Записка.Доступ  <- Надел.Доступ <- Рамка.Доступ *)
                               наделД(Записка.Доступ)
                              )
  ИНАЧЕ
  КОН
КОН Приём;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~общедоступная ЗАДАЧА~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА                                                         (*(Записка.Вид)*)
       Изменить-(запискаД:Записка.Доступ; текст-:ЦЕПЬ);
УКАЗ
  СПИСАТЬ(текст,запискаД.текст);
      Отрисовка(запискаД)
КОН Изменить;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~общедоступная ЗАДАЧА~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА                                                         (*(Записка.Вид)*)
       Из4хЦел-(запискаД:Записка.Доступ; описание-:ЦЕПЬ;
                                       ц1,ц2,ц3,ц4:ЦЕЛ);
УКАЗ
  Текст.Из4хЦел(описание,ц1,ц2,ц3,ц4,запискаД.текст);
  Отрисовка(запискаД)
КОН Из4хЦел;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~общедоступная ЗАДАЧА~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА                                                         (*(Записка.Вид)*)
       Создать-(верх,лево,строк,колонок:ЦЕЛ;
                                 текст-:ЦЕПЬ):Записка.Доступ;
ПЕР
                    запискаД:Доступ;
УКАЗ
            СОЗДАТЬ(запискаД);
      СПИСАТЬ(текст,запискаД.текст);
  Надел.Подготовить(запискаД,
                       верх,
                       лево,
                      строк,
                    колонок,
      {Надел.признакГлухой},
                      Приём   (* посылок для <наделД> *)
                   );
           ВОЗВРАТ запискаД
КОН Создать;

КОН Записка.
