(*~\Глагол\Отделы\Поле\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                            ОТДЕЛ Подложка;
(*============================================================================* 
 * НАЗНАЧЕНИЕ: подложка под поле
 *============================================================================*)

ИСПОЛЬЗУЕТ 
  Надел,
  Поле,
        (*  \Глагол\               *)
 оЦепи    ИЗ "..\..\Отделы\Иное\",
        (*  \Глагол\               *)
  Окно    ИЗ "..\..\Отделы\Обмен\",
  Ввод    ИЗ "..\..\Отделы\Обмен\";

ВИД
  Доступ- = ДОСТУП К Вид;  (* Подложка.Доступ <- Надел.Доступ <- Рамка.Доступ *)
                     Вид- =
  НАБОР (Надел.Вид)        (* Подложка.Вид    <- Надел.Вид    <- Рамка.Вид    *)
    заголовок:Надел.РядНадпись
  КОН;

(*-----------------------------------------локальная ЗАДАЧА-------------------*)
ЗАДАЧА                                                        (*(Подложка.Вид)*)
       Отрисовка(подложкаД:Подложка.Доступ);
ПЕР
  позЗаглавия:ЦЕЛ;
  вс,лк,нс,пк:ЦЕЛ;
УКАЗ
  вс:=подложкаД.вс;
  лк:=подложкаД.лк;
  нс:=подложкаД.нс;
  пк:=подложкаД.пк;
                             (* прямоугольник *)
  Надел.Очистить(подложкаД);
  Окно.Рамка2(вс,лк,нс,пк);
  Окно.Тень(вс,лк,нс,пк);
                             (* посерёдке будет заголовок *)

  позЗаглавия:=(лк+пк-ДЛИНА(подложкаД.заголовок)+1) ДЕЛИТЬ 2;
  Окно.ЦепьЗнаков(вс,позЗаглавия,вс,пк,подложкаД.заголовок)
КОН Отрисовка;

(*-----------------------------------------локальная ЗАДАЧА-------------------*)
ЗАДАЧА                                          (* (Подложка.Вид <- Надел.Вид)*)(* приём посылок из вне (снаружи) *)
       Приём(наделД:Надел.Доступ;
           посылка+:Ввод.нПосылка); (* = Пустой.Вид; - абстрактный опорный набор *)
УКАЗ
                             (* анализ многоформия (полиморфизма) у <посылка> = Пустой.Вид *)
  ДЛЯ      посылка ВИДА
  | Поле.нОтрисовка: Отрисовка(
                                                             (* преобразование
                               наделД                  из Надел.Доступ в
                                      Подложка.Доступ  <- Надел.Доступ <- Рамка.Доступ *)
                               наделД(Подложка.Доступ)
                              )
  ИНАЧЕ
  КОН
КОН Приём;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~общедоступная ЗАДАЧА~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА                                                        (*(Подложка.Вид)*)
       Создать-(верх,лево,строк,колонок:ЦЕЛ;
                             заголовок-:ЦЕПЬ):Подложка.Доступ;
ПЕР
                    подложкаД:Доступ;
УКАЗ
            СОЗДАТЬ(подложкаД);
  Надел.Подготовить(подложкаД,
                         верх,
                         лево,
                        строк,
                      колонок,
        {Надел.признакГлухой},
                        Приём   (* посылок для <наделД> *)
                   );
  ЕСЛИ
       заголовок # ""
  ТО
                             подложкаД.заголовок:=" ";
    оЦепи.ДобавитьВКонец(    подложкаД.заголовок,заголовок);
    оЦепи.ДобавитьВКонецЗнак(подложкаД.заголовок," ")
  КОН;
                     ВОЗВРАТ подложкаД
КОН Создать;

КОН Подложка.
