(*~\Глагол\Отделы\ЧисАн\64\к\Ряд\ВводВывод\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                                 ОТДЕЛ крВектВВ;
(*============================================================================*
 * НАЗНАЧЕНИЕ: (ввод из файла)/(вывод в файл) и печать на экран векторов
 *                      комплексных чисел (64 разряда) в виде ряда из 2-х вещ.
 *============================================================================*)

ИСПОЛЬЗУЕТ 
 дМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\д\",

крМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к\Ряд\",  
крВектор  ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к\Ряд\",

  ИзФайла ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
   ВФайл  ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
  НаЭкран ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\";

ВИД
(*
основной Вид отдела:
                     Вид- = РЯД ИЗ крМатем.Вид; (* вектор  из компл.чисел в виде ряда из 2-х вещ. *)
  Доступ- = ДОСТУП К Вид;              (* доступ к вектору из компл.чисел в виде ряда из 2-х вещ. *)
*)
        (* вид Вещ - это удвоенная точность 64 разряда (16 десятичных знаков) *)
  Вещ = дМатем.Вещ;                   (* локально *)


(*-оооооооооооооо- опережающие определения/заготовки задач -ооооооооооооооооо-*)


ЗАДАЧА^ ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;

ЗАДАЧА^ изФайла-(потокЧтеД:ИзФайла.ДкПотоку):крВектор.Доступ;

ЗАДАЧА^ наЭкран-(описание-:ЦЕПЬ;
                        кВект- :крВектор.Вид);

ЗАДАЧА^ наЭкранДвух-(описание-:ЦЕПЬ;
                             кВек1-,
                             кВек2- :крВектор.Вид);

ЗАДАЧА^ вФайл-(выходФайл:ВФайл.ДкПотоку;
                     описание-:ЦЕПЬ;
                        кВект-:крВектор.Вид);

ЗАДАЧА^ вФайлДвух-(выходФайл:ВФайл.ДкПотоку;
                         описание-:ЦЕПЬ;
                           кВек1-,
                           кВек2- :крВектор.Вид);
 
    
(*=рррррррррррррррррррррррр= реализация задач =рррррррррррррррррррррррррррррр=*)


(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;
(*
 * Цель:  если возможно, то открыть поток на чтение, иначе АВОСТ
 *----------------------------------------------------------------------------*
 * До:    <имяФайла> - имя считываемого файла
 * Ответ: открытый на чтение поток (ДОСТУП к Потоку)
 *)
ПЕР
       потокД:ИзФайла.ДкПотоку;
УКАЗ
       потокД:=ИзФайла.Открыть(имяФайла);
  ЕСЛИ
       потокД = ПУСТО
  ТО
    НаЭкран.ВсяЦепь('^Файл "');
    НаЭкран.ВсяЦепь(имяФайла);
    НаЭкран.ВсяЦепь('" не найден.^');
    СТОП(1) 
  КОН;
          потокД.цВидЗнаков:=ИзФайла.знУни;
  ВОЗВРАТ потокД
КОН ОткрытиеФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА изФайла-(потокЧтеД:ИзФайла.ДкПотоку):крВектор.Доступ;
(*
 * Цель: прочитать из потока размер комплексного вектора-строки (число столбцов),
 *       создать вектор из комплексных чисел в виде ряда из 2-х вещ.
 *       и заполнить его данными из этого потока
 *----------------------------------------------------------------------------*
 * До:    <потокЧтеД> - открытый на чтение поток
 * Ответ: доступ к созданному вектору комплексных в виде ряда из 2-х вещ.               
 *)
ПЕР
  j,столбцов:ЦЕЛ;
  дT,мT:Вещ;
          кВыхВекД:крВектор.Доступ;
УКАЗ
                   столбцов:=ИзФайла.Цел32(потокЧтеД);
  СОЗДАТЬ(кВыхВекД,столбцов);

  ОТ j:=0 ДО столбцов-1 ВЫП
                         дT:=ИзФайла.Вещ64(потокЧтеД);
                         мT:=ИзФайла.Вещ64(потокЧтеД);
    крМатем.алгебрВид(дT,мT,кВыхВекД[j])
  КОН;
  ВОЗВРАТ кВыхВекД
КОН изФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкран-(описание-:ЦЕПЬ;
                        кВект- :крВектор.Вид);
(*
 * Цель:  вывести на экран содержимое вектора <кВект> из компл.чисел в виде ряда из 2-х вещ.
 *----------------------------------------------------------------------------*
 * До:   <описание> - описатель печати комплексного элемента из вектора компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)"
 *       <кВект>    - вектор из  компл.чисел в виде ряда из 2-х вещ.
 *)
ПЕР
  j:ЦЕЛ;
УКАЗ
  ОТ j:=0 ДО РАЗМЕР(кВект)-1 ВЫП
    НаЭкран.Вещ4числа(
                            описание,            (* должно иметь (%23.17f; %23.17f) *)
                                    кВект[j][0],кВект[j][1],0,0)
  КОН; 
    НаЭкран.ВсяЦепь('^')  (* перевод строки *)
КОН наЭкран;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА вФайл-(выходФайл:ВФайл.ДкПотоку;
                    описание-:ЦЕПЬ;
                      кВект- :крВектор.Вид);
(*
 * Цель: записать в вых.файл содержимое вектора <кВект> из компл.чисел в виде ряда из 2-х вещ.
 *----------------------------------------------------------------------------*
 * До:  <выходФайл> - открытый для записи поток - выходной файл
 *       <описание> - описатель печати комплексного элемента из вектора компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)"
 *       <кВект>    - вектор из компл.чисел в виде ряда из 2-х вещ.
 *)
ПЕР
  j:ЦЕЛ;
УКАЗ
  ОТ j:=0 ДО РАЗМЕР(кВект)-1 ВЫП
    ВФайл.Вещ4числа(выходФайл,
                             описание,           (* должно иметь (%23.17f; %23.17f) *)
                                      кВект[j][0],кВект[j][1],0,0)
  КОН;
    ВФайл.ЦепьЗнаков(выходФайл,'^')  (* перевод строки *)
КОН вФайл;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкранДвух-(описание-:ЦЕПЬ;
                            кВек1-,
                            кВек2- :крВектор.Вид);
(*
 * Цель:  вывести на экран содержимое 2-х векторов <кВек1>,<кВек2> из компл.чисел в виде ряда из 2-х вещ.
 *----------------------------------------------------------------------------*
 * До:   <описание> - описатель печати 2-х комплексных элементов из 2-х векторов компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)   (%12.5f; %12.5f)"
 *  <кВек1>,<кВек2> - векторы одинаковой длины
 *)
ПЕР
  i:ЦЕЛ;
УКАЗ
  ОТ i:=0 ДО РАЗМЕР(кВек1)-1 ВЫП
    НаЭкран.Вещ4числа(
                            описание,             (* должно иметь (%12.5f; %12.5f)   (%12.5f; %12.5f) *)
                                    кВек1[i][0],кВек1[i][1],
                                    кВек2[i][0],кВек2[i][1])
  КОН; 
    НаЭкран.ВсяЦепь('^')  (* перевод строки *)
КОН наЭкранДвух;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА вФайлДвух-(выходФайл:ВФайл.ДкПотоку;
                        описание-:ЦЕПЬ;
                          кВек1-,
                          кВек2- :крВектор.Вид);
(*
 * Цель: записать в вых.файл содержимое 2-х векторов <кВек1>,<кВек2> из компл.чисел в виде ряда из 2-х вещ.
 *----------------------------------------------------------------------------*
 * До:  <выходФайл> - открытый для записи поток - выходной файл
 *       <описание> - описатель печати 2-х комплексных элементов из 2-х векторов компл.чисел в виде ряда из 2-х вещ.
 *                         (см. \Отделы\Обмен\Текст.отд)
 *                                         например <описание>="^ (%12.5f; %12.5f)  (%12.5f; %12.5f)"
 *  <кВек1>,<кВек2> - векторы одинаковой длины
 *)
ПЕР
  i:ЦЕЛ;
УКАЗ
  ОТ i:=0 ДО РАЗМЕР(кВек1)-1 ВЫП
    ВФайл.Вещ4числа(выходФайл,
                             описание,            (* должно иметь (%12.5f; %12.5f)  (%12.5f; %12.5f) *)
                                      кВек1[i][0],кВек1[i][1],
                                      кВек2[i][0],кВек2[i][1])
  КОН;
    ВФайл.ЦепьЗнаков(выходФайл,'^')  (* перевод строки *)
КОН вФайлДвух;
 
КОН крВектВВ.
