(*~\Глагол\Отделы\ЧисАн\64\к.N\Набор\ВводВывод\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                                     ОТДЕЛ кнМатрВВ;
(*============================================================================*
 * НАЗНАЧЕНИЕ: (ввод из файла)/(вывод в файл) и печать на экран матриц
 *                               комплексных чисел (64 разряда) в виде набора
 *============================================================================*)

ИСПОЛЬЗУЕТ 
 дМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\д\",

кнМатем   ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к\Набор\",
кнМатрица ИЗ "..\..\..\..\..\..\Отделы\ЧисАн\64\к.N\Набор\",

  ИзФайла ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
   ВФайл  ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\",
  НаЭкран ИЗ "..\..\..\..\..\..\Отделы\Обмен\ВводВывод\";

ВИД
        (* вид Вещ - это удвоенная точность 64 разряда (16 десятичных знаков) *)
  Вещ = дМатем.Вещ;                   (* локально *)


(*-оооооооооооооо- опережающие определения/заготовки задач -ооооооооооооооооо-*)


ЗАДАЧА^ ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;

ЗАДАЧА^ изФайла-(потокЧтеД:ИзФайла.ДкПотоку):кнМатрица.Доступ;

ЗАДАЧА^ наЭкран-(описание-:ЦЕПЬ;
                          кМатр-:кнМатрица.Вид; N0-,N1-:ЦЕЛ);

ЗАДАЧА^ вФайл-(выходФайл:ВФайл.ДкПотоку;
                     описание-:ЦЕПЬ;
                        кМатр-:кнМатрица.Вид; N0-,N1-:ЦЕЛ);


(*=рррррррррррррррррррррррр= реализация задач =рррррррррррррррррррррррррррррр=*)


(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;
(*
 * Цель:  если возможно, то открыть поток на чтение, иначе АВОСТ
 *----------------------------------------------------------------------------*
 * До:    <имяФайла> - имя считываемого файла
 * Ответ: открытый на чтение поток (ДОСТУП к Потоку)
 *)
ПЕР
       потокД:ИзФайла.ДкПотоку;
УКАЗ
       потокД:=ИзФайла.Открыть(имяФайла);
  ЕСЛИ
       потокД = ПУСТО
  ТО
(*
    НаЭкран.ОшибкаВпотоке-(имяФайла,' " не найден.^');
*)
    НаЭкран.ВсяЦепь('^Файл "');
    НаЭкран.ВсяЦепь(имяФайла);
    НаЭкран.ВсяЦепь('" не найден.^');
    СТОП(1) 
  КОН;
          потокД.цВидЗнаков:=ИзФайла.знУни;
  ВОЗВРАТ потокД
КОН ОткрытиеФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА изФайла-(потокЧтеД:ИзФайла.ДкПотоку):кнМатрица.Доступ;
(*
 * Цель: прочитать из вх.потока размер комплексной матрицы (строк, столбцов)
 *       создать матрицу комплексных чисел в виде набора
 *       и заполнить её данными из этого потока
 *----------------------------------------------------------------------------*
 * До:    <потокЧтеД> - открытый на чтение поток - входной файл
 * Ответ: доступ к выходной матрице комплексных чисел в виде набора
 *)
ПЕР
  i,j,строк,столбцов:ЦЕЛ;
  дT,мT:Вещ;
          кВыхМатД:кнМатрица.Доступ;
УКАЗ
                   строк:=         ИзФайла.Цел32(потокЧтеД);
                         столбцов:=ИзФайла.Цел32(потокЧтеД);
  СОЗДАТЬ(кВыхМатД,строк,столбцов);

  ОТ i:=0 ДО строк-1 ВЫП
    ОТ j:=0 ДО столбцов-1 ВЫП
                               дT:=ИзФайла.Вещ64(потокЧтеД);
                               мT:=ИзФайла.Вещ64(потокЧтеД);
      кнМатем.алгебрВид(дT,мT,кВыхМатД[i,j])
    КОН 
  КОН;
  ВОЗВРАТ кВыхМатД
КОН изФайла;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкран-(описание-:ЦЕПЬ;
                         кМатр-:кнМатрица.Вид; N0-,N1-:ЦЕЛ);
(*
 * Цель: вывести на экран содержимое комплексной матрицы <кМатр> 
 *----------------------------------------------------------------------------*
 * До:    <описание> - описатель печати элемента матрицы (см. Текст.отд)
 *        <кМатр>    - прямоугольная комплексная матрица N0xN1 из наборов       
 *)
ПЕР
  i,j:ЦЕЛ;
          (* N0,N1,*)    (* размеры матрицы >= рабочие размеры матрицы N0xN1 - любые заданные *)
УКАЗ
  ОТ i:=0 ДО N0(*РАЗМЕР(кМатр,0)*)-1 ВЫП
    ОТ j:=0 ДО N1(*РАЗМЕР(кМатр,1)*)-1 ВЫП
      НаЭкран.Вещ4числа(описание,кМатр[i,j].д,кМатр[i,j].м,0,0)
    КОН;       
               (* переход на новую строку для печати следующей строки матрицы *)
      НаЭкран.ВсяЦепь('^')  (* перевод строки *)
  КОН
КОН наЭкран;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА вФайл-(выходФайл:ВФайл.ДкПотоку;
                    описание-:ЦЕПЬ;
                       кМатр-:кнМатрица.Вид; N0-,N1-:ЦЕЛ);
(*
 * Цель: записать в выходной файл содержимое комплексной матрицы <кМатр> 
 *----------------------------------------------------------------------------*
 * До: <выходФайл> - открытый для записи поток - выходной файл
 *      <описание> - описатель печати элемента матрицы (см. Текст.отд)
 *        <кМатр>  - прямоугольная комплексная матрица N0xN1 из наборов      
 *)
ПЕР
  i,j:ЦЕЛ;
          (* N0,N1,*)    (* размеры матрицы >= рабочие размеры матрицы N0xN1 - любые заданные *)
УКАЗ
  ОТ i:=0 ДО N0(*РАЗМЕР(кМатр,0)*)-1 ВЫП
    ОТ j:=0 ДО N1(*РАЗМЕР(кМатр,1)*)-1 ВЫП
      ВФайл.Вещ4числа(выходФайл,
                  описание,кМатр[i,j].д,кМатр[i,j].м,0,0)
    КОН;
               (* переход на новую строку для печати следующей строки матрицы *)
      ВФайл.ЦепьЗнаков(выходФайл,'^')  (* перевод строки *)
  КОН
КОН вФайл;
 
КОН кнМатрВВ.
