(*~\Глагол\Отделы\ЧисАн\32\д\ВводВывод\~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
(**)                             ОТДЕЛ дВектВВ;
(*============================================================================*
 * НАЗНАЧЕНИЕ: (ввод из файла)/(вывод в файл) и печать на экран векторов
 *                                          действительных чисел (32 разряда)
 *============================================================================*)

ИСПОЛЬЗУЕТ 
 дВектор  ИЗ "..\..\..\..\..\Отделы\ЧисАн\32\д\",

  ИзФайла ИЗ "..\..\..\..\..\Отделы\Обмен\ВводВывод\",
   ВФайл  ИЗ "..\..\..\..\..\Отделы\Обмен\ВводВывод\",
  НаЭкран ИЗ "..\..\..\..\..\Отделы\Обмен\ВводВывод\";


(*=рррррррррррррррррррррррр= реализация задач =рррррррррррррррррррррррррррррр=*)


(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА ОткрытиеФайла-(имяФайла-:ЦЕПЬ):ИзФайла.ДкПотоку;
(*
 * Цель:  если возможно, то открыть поток на чтение, иначе АВОСТ
 *----------------------------------------------------------------------------*
 * До:    <имяФайла> - имя считываемого файла
 * Ответ: открытый на чтение поток (ДОСТУП к Потоку)
 *)
ПЕР
       потокД:ИзФайла.ДкПотоку;
УКАЗ
       потокД:=ИзФайла.Открыть(имяФайла);
  ЕСЛИ
       потокД = ПУСТО
  ТО
(*
    НаЭкран.ОшибкаВпотоке-(имяФайла,' " не найден.^');
*)
    НаЭкран.ВсяЦепь('^Файл "');
    НаЭкран.ВсяЦепь(имяФайла);
    НаЭкран.ВсяЦепь('" не найден.^');
    СТОП(1) 
  КОН;
          потокД.цВидЗнаков:=ИзФайла.знУни;
  ВОЗВРАТ потокД
КОН ОткрытиеФайла;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА изФайла-(ч:ИзФайла.ДкПотоку):дВектор.Доступ;
(*
 * Цель: прочитать из потока размер вектора-строки (число столбцов),
 *       создать вектор из вещ32
 *       и заполнить его данными из этого потока
 *----------------------------------------------------------------------------*
 * До:    <ч> - открытый на чтение поток
 * Ответ: доступ к созданному вектору действительных                         
 *)
ПЕР
  j,столбцов:ЦЕЛ;
          дВыхВекД:дВектор.Доступ;
УКАЗ
                   столбцов:=ИзФайла.Цел32(ч);
  СОЗДАТЬ(дВыхВекД,столбцов);
  ОТ j:=0 ДО столбцов-1 ВЫП
          дВыхВекД[j]:=      ИзФайла.Вещ32(ч)
  КОН;
  ВОЗВРАТ дВыхВекД
КОН изФайла;
 

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкран-(описание-:ЦЕПЬ; дВект-:дВектор.Вид);
(*
 * Цель:  вывести на экран содержимое вектора <дВект> из вещ32
 *----------------------------------------------------------------------------*
 * До:    <описание> - описатель печати элемента вектора из вещ32
 *                         (см. \Отделы\Числа\Текст.отд)
 *        <дВект>    - печатаемый вектор-строка из вещ32
 *)
ПЕР
  j:ЦЕЛ;
УКАЗ
  ОТ j:=0 ДО РАЗМЕР(дВект)-1 ВЫП
      НаЭкран.Вещ4числа(описание,дВект[j],0,0,0)
  КОН; 
      НаЭкран.ВсяЦепь('^')  (* перевод строки *)
КОН наЭкран;
 
(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкранДвух-(описание-:ЦЕПЬ; дВек1-,дВек2-:дВектор.Вид);
(*
 * Цель:  вывести на экран содержимое двух векторов из вещ32
 *                                       <дВек1, дВек2> 
 *----------------------------------------------------------------------------*
 * До: <описание> - описатель печати элементов 2-х векторов из вещ32
 *                         (см. \Отделы\Числа\Текст.отд)
 *     <дВек1,дВек2> - два печатаемых вектора-строки одинаковой длины          
 *)
ПЕР
  j:ЦЕЛ;
УКАЗ
  ОТ j:=0 ДО РАЗМЕР(дВек1)-1 ВЫП
      НаЭкран.Вещ4числа(описание,
                                      дВек1[j],дВек2[j],0,0)
  КОН; 
      НаЭкран.ВсяЦепь('^')  (* перевод строки *)
КОН наЭкранДвух;

(*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*)
ЗАДАЧА наЭкранЧетырёх-(описание-:ЦЕПЬ; дВек1-,дВек2-,
                                       дВек3-,дВек4-:дВектор.Вид);
(*
 * Цель:  вывести на экран содержимое четырёх векторов из вещ32
 *                                          <дВек1 ,дВек2, дВек3, дВек4> 
 *----------------------------------------------------------------------------*
 * До: <описание> - описатель печати элементов 4-х векторов из вещ32
 *                         (см. \Отделы\Числа\Текст.отд)
 *     <дВек1,дВек2,дВек3,дВек4> - 4 печатаемых вектора-строки одинаковой длины          
 *)
ПЕР
  j:ЦЕЛ;
УКАЗ
  ОТ j:=0 ДО РАЗМЕР(дВек1)-1 ВЫП
      НаЭкран.Вещ4числа(описание,
                                      дВек1[j],дВек2[j],
                                      дВек3[j],дВек4[j])
  КОН; 
      НаЭкран.ВсяЦепь('^')  (* перевод строки *)
КОН наЭкранЧетырёх;
 

КОН дВектВВ.
